Обмен данными онлайн через Веб-сервис с использованием обработки "Универсальный обмен данными XML"

Публикация № 557914

Обмен - Обмен через XML

Обмен данными Онлайн В режиме реального времени Веб-сервис Универсальный обмен данными XML Конвертация данных

174
Доработка позволяет организовать двухсторонний обмен данными в режиме реального времени между любыми конфигурациями (типовые, самописные, обычные формы, управляемые формы). Также предлагается вариант в виде расширения конфигурации (.cfe) для конфигураций стоящих на поддержке без возможности изменения. В обмене может участвовать любое количество баз. Правила обмена подготавливаются с использованием конфигурации "Конвертация данных".

К слову, в БСП 2.3 уже реализован универсальный обмен данными через Веб-сервис, но для его внедрения необходимо включение в конфигурацию всех сопутствующих подсистем БСП, что не всегда представляется возможным. Особенно, если текущая конфигурация на обычных формах (БСП 2.3 ориентировано на управляемые формы).

В представленных алгоритмах были проработаны следующие вопросы:

1. Запуск синхронизации производится в реальном режиме времени при записи (удалении) объекта (документа, справочника), но только если запись выполняется интерактивно. То есть, при пакетном перепроведении документов при восстановлении последовательности или из обработки "Групповая обработка справочников и документов" синхронизация не требуется (предполагается, что движения документов не переносятся, а формируются при проведении).

2. Предусмотрен механизм гарантированной доставки данных в базу приемник. Для этих целей, при запуске синхронизации, объект предварительно регистрируется в плане обмена. В случае сбоя синхронизации по ежеминутному регламентному заданию выполняется проверка наличия зарегистрированных объектов в плане обмена и производится повторная попытка передачи данных в базу приемник. Далее, в случае успешности передачи данных, регистрация объекта в плане обмена удаляется.

3. Для исключения задержек при записи объектов, синхронизация запускается асинхронно в фоновом задании. Если же требуется организовать отказ от проведения документа в текущей базе в зависимости от успешности проведения этого документа в базе приемнике, имеется возможность предусмотреть запуск синхронизации в основном потоке (по опыту, документ реализация товаров в УПП имеющий в табличной части до 10 строчек синхронизируется за 1-2 сек), в этом случае производится ожидание завершения синхронизации и в зависимости от успешности проведения выставляется отказ и дублируется сообщение о причине неуспешности, переданное из базы приемника.

4. Для универсальности данные передаются в базу приемник в формате XML, сформированными программно с помощью обработки "Универсальный обмен данными XML" по правилам обмена, подготовленными в конфигурации "Конвертация данных". Соответственно, на стороне приемника производится загрузка этой же обработкой. Как правило, во всех типовых конфигурациях данная обработка присутствует, а для самописных можно загрузить из состава .cf данной публикации.

5. Пакет передаваемых данных должен иметь минимальный объем данных, Чтобы не загружать сетевые службы и Веб-сервер. Для этих целей, предусмотрено:

- за один раз производится выгрузка только одного объекта (с подчиненными объектами, выгруженными по ссылкам, если это справочник);

- при разработке правил обмена для всех документов устанавливается режим "Не выгружать объекты свойств источника по ссылкам". В этом случае исключается избыточность передаваемых данных. Если же в реквизите встречается ссылка на элемент объекта, который не включен в состав регистрируемых объектов плана обмена (то есть данный вид объектов самостоятельно не синхронизируется) и эта ссылка не была найдена в базе приемнике (в терминах обработки это фиктивная ссылка), то формируется список фиктивных ссылок, который возвращается в базу источник и рекурсивно инициируется синхронизация для этих объектов.

6. Как следствие из предыдущего пункта, проведение документа в базе приемнике реализовано отдельным запросом после полной передачи всего пакета вместе с рекурсивной синхронизацией фиктивных ссылок по предыдущему пункту. Так как для документов отключена выгрузка объектов свойств источника по ссылкам, то на момент первичной записи документа в нем могут присутствовать фиктивные ссылки, из за которых нормальное проведение документа в этот момент невозможно. 

Реализация

1. Для всех синхронизируемых объектов в форме элемента справочника (форме документа) в обработчике "При открытии" необходимо добавить следующий код:
Процедура ПриОткрытии()
	
	ДополнительныеСвойства.Вставить("СинхронизироватьПриЗаписи");
	
КонецПроцедуры
2. Добавляем подписки на события

ПодпискаОбъектПриЗаписи

ПодпискаОбъектПередУдалением

3. Общий модуль "ЛУ_СинхронизацияКлиентСервер" (Сервер, Клиент Обычное приложение) - обработчики подписок
Процедура ОбъектПриЗаписиСинхронизировать(Источник, Отказ) Экспорт
	
	ПланОбменаРегистрацияИзменений(ПланыОбмена.ЛУ_WebСервис, Источник, Отказ);
	
КонецПроцедуры

Процедура ОбъектПередУдалениемСинхронизировать(Источник, Отказ) Экспорт
	
	ПланОбменаРегистрацияИзменений(ПланыОбмена.ЛУ_WebСервис, Источник, Отказ, Истина);
	
КонецПроцедуры

Процедура ПланОбменаРегистрацияИзменений(ПланОбмена, Источник, Отказ, Удаление=Ложь) Экспорт
	
	#Если НЕ ТолстыйКлиентОбычноеПриложение Тогда
		Возврат;
	#КонецЕсли
		
	Если Отказ или Источник.ОбменДанными.Загрузка Тогда 
		Возврат; 
	КонецЕсли;
	
	Если НЕ (Источник.ДополнительныеСвойства.Свойство("СинхронизироватьПриЗаписи") или Удаление)  Тогда
		Возврат; 
	КонецЕсли;
	
	ПланОбменаМетаданные = ПланОбмена.ПустаяСсылка().Метаданные();
	Если НЕ ПланОбменаМетаданные.Состав.Содержит(Источник.Метаданные()) Тогда
		Возврат; 
	КонецЕсли;

	// Регистрация изменениий в плане обмена
	ВыборкаУзлов = ПланОбмена.Выбрать();
	Пока ВыборкаУзлов.Следующий() Цикл
		
		ТекущийУзел = ВыборкаУзлов.Ссылка;
		Если ТекущийУзел = ПланОбмена.ЭтотУзел() Тогда
			Продолжить;
		КонецЕсли;
		
		Если НЕ ТекущийУзел.Синхронизировать Тогда 
			Продолжить;
		КонецЕсли;
		
		ОбъектРегистрации = ?(Удаление, Новый УдалениеОбъекта(Источник.Ссылка), Источник.Ссылка);
		ПланыОбмена.ЗарегистрироватьИзменения(ТекущийУзел, ОбъектРегистрации);
		
	КонецЦикла;
	
	ЛУ_СинхронизацияВызовСервера.ПланОбменаСинхронизироватьАсинхронно(ПланОбменаМетаданные.Имя);

КонецПроцедуры
4. План обмена ЛУ_WebСервис

Структура плана обмена

Здесь:

  • Синхронизировать - булево,
  • Сервер, База, Пользователь, Пароль - Строка, 100, переменная
  • ПравилаКонвертации - ХранилищеЗначения (в форме узла реализована загрузка в этот реквизит правил обмена из файла XML)
5. Общий модуль "ЛУ_СинхронизацияВызовСервера" (Сервер, Вызов сервера)
(для наглядности из листингов исключены все конструкции связанные с обработкой исключений, вывода ошибок, и вспомогательные методы)
Процедура ПланОбменаСинхронизировать(ИмяПланаОбмена) Экспорт
	
	ПланОбмена = ПланыОбмена[ИмяПланаОбмена];
	
	ВыборкаУзлов = ПланОбмена.Выбрать();
	Пока ВыборкаУзлов.Следующий() Цикл
		
		ТекущийУзел = ВыборкаУзлов.Ссылка;
		Если ТекущийУзел = ПланОбмена.ЭтотУзел() Тогда
			Продолжить;
		КонецЕсли;
		
		Если НЕ ТекущийУзел.Синхронизировать Тогда 
			Продолжить;
		КонецЕсли;
		
		ИмяСобытияДляЖурнала = "ПланОбмена." + ИмяПланаОбмена + " " + ПланОбмена.ЭтотУзел().Код + " -> " + ТекущийУзел.Код;
		
		ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();
		ЗаписьСообщенияXML = Новый ЗаписьXML;
		ЗаписьСообщенияXML.УстановитьСтроку();
		
		Попытка
			ЗаписьСообщения.НачатьЗапись(ЗаписьСообщенияXML, ТекущийУзел);
		Исключение
			// ТекущийУзел заблокирован, пока пропустим, следующая попытка будет по регламентному заданию через 60 сек
			Продолжить;	
		КонецПопытки;
		
		НомерСообщения = ЗаписьСообщения.НомерСообщения;
		МетаданныеДокументы = Метаданные.Документы;
		МассивУдаляемыхОбъектов = Новый Массив;
		МассивОбъектов = Новый Массив;
		
		Выборка = ПланыОбмена.ВыбратьИзменения(ТекущийУзел, НомерСообщения);
		Пока Выборка.Следующий() Цикл
			// В этом цикле только подготовим массив объектов, содержащихся в сообщении плана обмена
			// Чтобы побыстрее освободить ЗаписьСообщения
			// (до вызова метода ЗакончитьЗапись() в плане обмена устанавливается исключительная блокировка)
			Объект = Выборка.Получить();
			Если ТипЗнч(Объект) = Тип("УдалениеОбъекта") Тогда
				МассивУдаляемыхОбъектов.Добавить(Объект);
			ИначеЕсли НЕ МетаданныеДокументы.Содержит(Объект.Ссылка.Метаданные()) Тогда
				МассивОбъектов.Вставить(0, Объект.Ссылка);  // Документы сдвигаем в конец массива
			Иначе
				МассивОбъектов.Добавить(Объект.Ссылка);
			КонецЕсли;
		КонецЦикла;
		
		Если МассивОбъектов.Количество() = 0 и МассивУдаляемыхОбъектов.Количество() = 0 Тогда
			ЗаписьСообщения.ПрерватьЗапись(); // Освобождаем номер сообщения плана обмена
			Продолжить;
		КонецЕсли;
		ЗаписьСообщения.ЗакончитьЗапись(); // Фиксируем исходящее сообщение плана обмена данных
		// Полученный XML сообщения игнорируем. 
		// Так как в базе приемнике фиксация номеров входящих сообщений плана обмена не предусмотрена 
		// (В приемнике вообще может не быть корреспондирующего плана обмена при одностороннем обмене).
		ЗаписьСообщенияXML.Закрыть(); 
		
		// Передача измененных объектов в базу приемник
		Отказ = Ложь;
		ОбработкаОбмена = ИнициализироватьОбработкуОбмена(ТекущийУзел, ИмяСобытияДляЖурнала, Отказ);

		ФайлОбмена = Новый Файл(ОбработкаОбмена.ИмяФайлаОбмена);
		
		// Подключение
		LuExchange = ПолучитьWSПрокси(ТекущийУзел, "LuExchange.1cws", "http://www.LuExchange.ru", "LuExchange");
		
		// Удаляемые объекты // Поиск удаляемого объекта выполняется только по ссылке
		ВыгрузитьУдаляемыеОбъектыВБазуПриемник(ТекущийУзел, МассивУдаляемыхОбъектов, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала, Отказ);
		
		// Измененные объекты
		Для каждого ОбъектСсылка Из МассивОбъектов Цикл
			
			ОшибкаВыгрузкиОбъекта = Ложь;
			СтрокаЗагруженныеДокументы = ""; // Массив загруженных документов в базе приемнике (строка внутренняя) для инициации последующего проведения
			ВыгрузитьОбъектВБазуПриемник(ОбъектСсылка, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала, СтрокаЗагруженныеДокументы, ОшибкаВыгрузкиОбъекта);

			Если ОшибкаВыгрузкиОбъекта Тогда
				Отказ = Истина;
				Продолжить;	
			КонецЕсли;
			
			// Для выгруженных документов необходимо выполнить команду проведения или, если документ был распроведен, удалить движения
			ОшибкаПроведенияДокумента = Ложь;
			ОбработкаПризнакаПроведенияДокумента(СтрокаЗагруженныеДокументы, LuExchange, ИмяСобытияДляЖурнала, ОшибкаПроведенияДокумента);
				
			// Фиксируем успешную синхронизацию в плане обмена для объекта
			ПланыОбмена.УдалитьРегистрациюИзменений(ТекущийУзел, ОбъектСсылка);	
			
		КонецЦикла;
		
		УдалитьФайлы(ОбработкаОбмена.ИмяФайлаОбмена);
		
		Если НЕ Отказ Тогда
			// Фиксируем успешную синхронизацию в плане обмена для всего сообщения
			ПланыОбмена.УдалитьРегистрациюИзменений(ТекущийУзел, НомерСообщения);	
		КонецЕсли;
		
	КонецЦикла;
	
КонецПроцедуры
Процедура ВыгрузитьОбъектВБазуПриемник(ОбъектСсылка, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала, СтрокаЗагруженныеДокументы="", Отказ)
	
	// Получаем ДанныеXML
	ВыгруженоОбъектов = 0; 
	ДанныеXML = ПолучитьДанныеXMLПоПравиламКонвертации(ОбработкаОбмена, ОбъектСсылка, ВыгруженоОбъектов, ИмяСобытияДляЖурнала);
	
	// ExecuteExchange
	ТекстОшибки = "";
	ОшибкаВыгрузки = Ложь;
	СтрокаФиктивныеСсылки = "";
	Данные = Новый ХранилищеЗначения(ДанныеXML, Новый СжатиеДанных(9));
	ЗагруженоОбъектов = LuExchange.ExecuteExchange(Данные, ИмяСобытияДляЖурнала, СтрокаФиктивныеСсылки, СтрокаЗагруженныеДокументы, ТекстОшибки);

	// Фиктивные ссылки (выгружаем объекты по ссылкам)
	ОбработкаФиктивныхСсылок(СтрокаФиктивныеСсылки, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала, ОшибкаВыгрузки);
	
КонецПроцедуры
Процедура ОбработкаФиктивныхСсылок(СтрокаФиктивныеСсылки, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала, Отказ)
	
	Если ПустаяСтрока(СтрокаФиктивныеСсылки) Тогда
		Возврат;
	КонецЕсли;
	
	ФиктивныеСсылки = ЗначениеИзСтрокиВнутр(СтрокаФиктивныеСсылки);
	Для каждого ФиктивнаяСсылка Из ФиктивныеСсылки Цикл
		ФиктивнаяСсылка = СтрЗаменить(ФиктивнаяСсылка, ".", Символы.ПС);
		ВидПриемника = СтрПолучитьСтроку(ФиктивнаяСсылка, 1);
		ТипПриемника = СтрПолучитьСтроку(ФиктивнаяСсылка, 2); 
		УИД = СтрПолучитьСтроку(ФиктивнаяСсылка, 3);
		
		// Здесь тип объекта соответствует метаданным базы приемника, 
		// для обработки необходимо привести к соответствующему типу текущей базы
		// Найдем корреспондирующий тип по правилам обмена
		ПравилоКонвертации = ОбработкаОбмена.ТаблицаПравилКонвертации.Найти(ВидПриемника+"Ссылка."+ТипПриемника, "Приемник");
		Если ПравилоКонвертации = Неопределено Тогда
			Продолжить;
		КонецЕсли;
		
		TypeOf = СтрЗаменить(ПравилоКонвертации.ТипИсточника, ".", Символы.ПС);
		ВидИсточника = СтрПолучитьСтроку(TypeOf, 1);
		ТипИсточника = СтрПолучитьСтроку(TypeOf, 2);
		
		Если ВидИсточника = "ДокументСсылка" Тогда
			МенеджерОбъекта = Документы[ТипИсточника];
		ИначеЕсли ВидИсточника = "СправочникСсылка" Тогда
			МенеджерОбъекта = Справочники[ТипИсточника];
		Иначе
			Отказ = Истина;
			Продолжить;	
		КонецЕсли;
		
		ОбъектСсылка = МенеджерОбъекта.ПолучитьСсылку(Новый УникальныйИдентификатор(УИД));
		
		НайденныйОбъект = ОбъектСсылка.ПолучитьОбъект();
		Если НайденныйОбъект = Неопределено Тогда
			Отказ = Истина;
			Продолжить;	
		КонецЕсли;
		
		ВыгрузитьОбъектВБазуПриемник(ОбъектСсылка, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала,, Отказ);
		
	КонецЦикла;

КонецПроцедуры
Процедура ОбработкаПризнакаПроведенияДокумента(СтрокаЗагруженныеДокументы, LuExchange, ИмяСобытияДляЖурнала, Отказ)
	
	Если ПустаяСтрока(СтрокаЗагруженныеДокументы) Тогда
		Возврат;
	КонецЕсли;
	
	// PostingDocuments
	ТекстОшибки = "";
	Отказ = LuExchange.PostingDocuments(СтрокаЗагруженныеДокументы, ТекстОшибки);

КонецПроцедуры
Функция ИнициализироватьОбработкуОбмена(ТекущийУзел, ИмяСобытияДляЖурнала, Отказ)
	
	// Инициализация
	ОбработкаОбмена = Обработки.УниверсальныйОбменДаннымиXML.Создать();
	ОбработкаОбмена.РежимОбмена = "Выгрузка";
	ОбработкаОбмена.ПостроительОтчета = Новый ПостроительОтчета;
	ОбработкаОбмена.НеВыводитьНикакихИнформационныхСообщенийПользователю = Истина;
	
	// Загрузка правил
	ПравилаОбмена = ТекущийУзел.ПравилаКонвертации.Получить();
	ОбработкаОбмена.ЗагрузитьПравилаОбмена(ПравилаОбмена, "Строка");
	ОбработкаОбмена.ИмяФайлаПравилОбмена = "Неопределено"; // Обходим глюк обработки, иначе она считает, что правила не загружены
	
	// ИмяФайлаОбмена	
	ОбработкаОбмена.ИмяФайлаОбмена = ПолучитьИмяВременногоФайла("xml");
	
	// Для всех правил конвертации справочников и документов рекомендуется по возможности устанавливать в ИСТИНА следующие свойства: 
	//	- Искать объект приемника по внутреннему идентификатору объекта источника;
	//	- При переносе объкта по ссылке НЕ создавать новый объект, а только переносить ссылку;
	// Для правил конвертации документов дополнительно рекомендуется устанавливать в ИСТИНА следующее свойство: 
	//	- Не выгружать объекты свойств источника по ссылкам;
	// В этом случае файл данных XML для выгружаемого объекта не будет содержать объекты выгружаемые по ссылкам. 
	// Это существенно уменьшит размер передаваемого файла и ускорит процесс синхронизации.
	// Выгрузка этих объектов при необходимости будет инициироваться автоматически.
	
	Возврат ОбработкаОбмена;
	
КонецФункции
Функция ПолучитьДанныеXMLПоПравиламКонвертации(ОбработкаОбмена, ОбъектСсылка, ВыгруженоОбъектов, ИмяСобытияДляЖурнала)
	
	МетаИмя = ОбъектСсылка.Метаданные().Имя;
	
	// Сначала все отключаем
	Для Каждого Строка из ОбработкаОбмена.ТаблицаПравилВыгрузки.Строки Цикл
		Строка.Включить = 0;
		ОбработкаОбмена.УстановитьПометкиПодчиненных(Строка, "Включить");
	КонецЦикла;
	
	// Включаем нужное правило
	СтрПравил = ОбработкаОбмена.ТаблицаПравилВыгрузки.Строки.Найти(МетаИмя, "Имя", Истина);
	
	Если СтрПравил = Неопределено Тогда
		Возврат Неопределено;
	КонецЕсли; 
	
	Если НЕ ЗначениеЗаполнено(СтрПравил.ИмяОбъектаДляЗапроса) Тогда
		Возврат Неопределено;
	КонецЕсли; 
	
	СтрПравил.Включить = 1;
	ОбработкаОбмена.УстановитьПометкиРодителей(СтрПравил, "Включить");
	
	// Отбор
	ИмяОтбора = СтрЗаменить(СтрПравил.ИмяОбъектаДляЗапроса, ".", "_");
	ПостроительОтчета = Новый ПостроительОтчета("ВЫБРАТЬ ПЕРВЫЕ 1 _.* ИЗ " + СтрПравил.ИмяОбъектаДляЗапроса + " КАК _ {ГДЕ _.Ссылка.* КАК " + ИмяОтбора + "}");
	
	Отбор = ПостроительОтчета.Отбор.Добавить(ИмяОтбора);
	Отбор.ВидСравнения = ВидСравнения.Равно;
	Отбор.Установить(ОбъектСсылка); 
	
	СтрПравил.ИспользоватьОтбор = Истина;
	СтрПравил.НастройкиПостроителя = ПостроительОтчета.ПолучитьНастройки();
	
	// Выгрузка
	ОбработкаОбмена.ВыполнитьВыгрузку();
	ВыгруженоОбъектов = ОбработкаОбмена.мСчетчикВыгруженныхОбъектов;
	ЧтениеТекста = Новый ЧтениеТекста;
	ЧтениеТекста.Открыть(ОбработкаОбмена.ИмяФайлаОбмена, КодировкаТекста.UTF8);
	СтрокаXML = ЧтениеТекста.Прочитать();
	ЧтениеТекста.Закрыть();
	
	Возврат СтрокаXML;
	
КонецФункции // ПолучитьДанныеXMLПоПравиламКонвертации()
Функция ПолучитьWSПрокси(Параметры, ИмяФайлаПубликации, URIПространстваИменСервиса, ИмяСервиса)
	
	Определения = Новый WSОпределения("http://"+Параметры.Сервер+"/"+Параметры.База+"/ws/"+ИмяФайлаПубликации+"?wsdl", Параметры.Пользователь, Параметры.Пароль);
	WSПрокси = Новый WSПрокси(Определения, URIПространстваИменСервиса, ИмяСервиса, ИмяСервиса+"Soap");
	WSПрокси.Пользователь = Параметры.Пользователь;
	WSПрокси.Пароль = Параметры.Пароль;
	Возврат WSПрокси;
	
КонецФункции
6. Настройка Веб-сервиса для базы приемника

Настройка Веб-сервиса для базы приемника

7. Модуль Веб-сервиса

Функция ExecuteExchange(DataXML, NameOfEvent, FictitiousObjects, UploadedDocuments, ErrorMessage)       

	УстановитьПривилегированныйРежим(Истина);
	
	Попытка
		
		ОбработкаОбмена = Обработки.УниверсальныйОбменДаннымиXML.Создать();
		ОбработкаОбмена.РежимОбмена = "Загрузка";
		ОбработкаОбмена.НеВыводитьНикакихИнформационныхСообщенийПользователю = Истина;
		ОбработкаОбмена.ЗагружатьДанныеВРежимеОбмена = Истина;
		ОбработкаОбмена.ЗаписыватьВИнформационнуюБазуТолькоИзмененныеОбъекты = Истина;
		ОбработкаОбмена.ОптимизированнаяЗаписьОбъектов = Истина;
		ОбработкаОбмена.ЗаписыватьРегистрыНаборамиЗаписей = Истина;
	
		РаботаВозможна = ОбработкаОбмена.ВыполнитьДействияПередЧтениемДанных(DataXML.Получить());
		Если НЕ РаботаВозможна Тогда
			ErrorMessage = "ExecuteExchange(1). ОбработкаОбмена.ВыполнитьДействияПередЧтениемДанных - работа не возможна";
			Возврат 0;
		КонецЕсли;	

		ОбработкаОбмена.ПроизвестиЧтениеДанных(ErrorMessage);
		Если НЕ ПустаяСтрока(ErrorMessage) Тогда
			Возврат 0;
		КонецЕсли;

		ОбработкаОбмена.ВыполнитьДействияПослеЗавершенияЧтенияДанных(); 

		// Подготовим для возврата в базу источник массивы Фиктивных ссылок и массив выгруженных документов
		МассивФиктивныхСсылок = Новый Массив;
		МассивЗагруженныхДокументов = Новый Массив;
		МетаданныеДокументы = Метаданные.Документы;
		Для каждого КлючИЗначение Из ОбработкаОбмена.ЗагруженныеОбъекты Цикл
			ОбъектСсылка = КлючИЗначение.Значение.СсылкаНаОбъект;
			ОбъектМетаданные = ОбъектСсылка.Метаданные();
			Если КлючИЗначение.Значение.СсылкаФиктивная Тогда  
				// Фиктивная ссылка - объект не найденный в базе приемнике и не выгруженный по ссылкам
				МассивФиктивныхСсылок.Добавить(ОбъектМетаданные.ПолноеИмя() + "." + XMLСтрока(ОбъектСсылка.Ссылка));
			ИначеЕсли МетаданныеДокументы.Содержит(ОбъектМетаданные) Тогда
				МассивЗагруженныхДокументов.Добавить(ОбъектСсылка.Ссылка);
			КонецЕсли;
		КонецЦикла;
		Если МассивФиктивныхСсылок.Количество() > 0 Тогда
			FictitiousObjects = ЗначениеВСтрокуВнутр(МассивФиктивныхСсылок);
		КонецЕсли;
		Если МассивЗагруженныхДокументов.Количество() > 0 Тогда
			UploadedDocuments = ЗначениеВСтрокуВнутр(МассивЗагруженныхДокументов);
		КонецЕсли;

	Исключение
		ErrorMessage = "ExecuteExchange(2). " + ОписаниеОшибки();
		Возврат 0;
	КонецПопытки;
	
	Возврат ОбработкаОбмена.мСчетчикЗагруженныхОбъектов;	
	
КонецФункции

Функция DeleteObject(TypeOf, UUID, ErrorMessage)
	
	УстановитьПривилегированныйРежим(Истина);
	Попытка
		
		TypeOf = СтрЗаменить(TypeOf, ".", Символы.ПС);
		ВидОбъекта = СтрПолучитьСтроку(TypeOf, 1);
		ТипОбъекта = СтрПолучитьСтроку(TypeOf, 2);

		Если ВидОбъекта = "ДокументСсылка" Тогда
			МенеджерОбъекта = Документы[ТипОбъекта];
		ИначеЕсли ВидОбъекта = "СправочникСсылка" Тогда
			МенеджерОбъекта = Справочники[ТипОбъекта];
		Иначе
			ErrorMessage = "DeleteObject(1). Ошибка получения менеджера объекта " + ВидОбъекта + "." + ТипОбъекта + "!";
			Возврат Истина;	
		КонецЕсли;
		
		ОбъектСсылка = МенеджерОбъекта.ПолучитьСсылку(Новый УникальныйИдентификатор(UUID));
		НайденныйОбъект = ОбъектСсылка.ПолучитьОбъект();
		Если НЕ НайденныйОбъект = Неопределено Тогда
			НайденныйОбъект.Удалить(); 
			// В базе приемнике удаление происходит без проверки ссылочной целостности
			// В некоторых схемах целесообразнее отключать данный функционал
			// а удаление выполнять соответствующей обработкой
			// ("ПометкаУдаления" синхронизируется обычным образом в ExecuteExchange)
		КонецЕсли;
			
	Исключение
		ErrorMessage = "DeleteObject(2). " + ОписаниеОшибки();
		Возврат Истина;
	КонецПопытки;
	
	Возврат Ложь;	
	
КонецФункции

Функция PostingDocuments(UploadedDocuments, ErrorMessage)
	
	УстановитьПривилегированныйРежим(Истина);
	Отказ = Ложь;
	Попытка
		
		МассивВыгруженныхДокументов = ЗначениеИзСтрокиВнутр(UploadedDocuments);
		Для каждого ДокументСсылка Из МассивВыгруженныхДокументов Цикл
			
			ДокументОбъект = ДокументСсылка.ПолучитьОбъект();
			Если ДокументОбъект = Неопределено Тогда
				Отказ = Истина;
				ErrorMessage = ErrorMessage + Символы.ПС + "PostingDocuments(1). Объект не найден: " + ДокументСсылка;
				Продолжить;
			КонецЕсли;
			
			// Проведение
			Если ДокументОбъект.Проведен Тогда
				Попытка
					ПолучитьСообщенияПользователю(Истина); // Очистим все предыдущие сообщения на момент проведения
					ДокументОбъект.Записать(РежимЗаписиДокумента.Проведение);
				Исключение
					Сообщения = ПолучитьСообщенияПользователю(Истина); // Вернем в базу источник ошибки проведения
					ТекстСообщения = "";
					Для каждого Сообщение Из Сообщения Цикл
						ТекстСообщения = ТекстСообщения + Символы.ПС + Сообщение.Текст;
					КонецЦикла;
					ErrorMessage = ErrorMessage + Символы.ПС + "PostingDocuments(2). " + ДокументСсылка + Символы.ПС + ОписаниеОшибки() + ТекстСообщения;
					Отказ = Истина;
					// Сбросим признак проведения
					ДокументОбъект.Проведен = Ложь;
					ДокументОбъект.ОбменДанными.Загрузка = Истина;
					ДокументОбъект.Записать(РежимЗаписиДокумента.Запись);
				КонецПопытки;
			КонецЕсли;
			
			// Если снят с проведения, очистим движения
			Если НЕ ДокументОбъект.Проведен Тогда
				Для каждого НаборДвижений Из ДокументОбъект.Движения Цикл
					НаборДвижений.Прочитать();
					Если НаборДвижений.Количество() > 0 Тогда
						НаборДвижений.Очистить();
						НаборДвижений.Записать();
					КонецЕсли;
				КонецЦикла;
			КонецЕсли;
			
		КонецЦикла;
		
	Исключение
		ErrorMessage = "PostingDocuments(3). " + ОписаниеОшибки();
		Отказ = Истина;
	КонецПопытки;
	
	Возврат Отказ;	
	
КонецФункции
8. Рекомендации
При  разработке правил конвертации очень сложно отлаживать правила в боевой схеме, поэтому для сложных конвертаций рекомендую сначало воспользоваться средствами отладки встроенными в обработку "Универсальный обмен данными XML", в этом случае имеется возможность подключить алгоритмы из правил в виде модулей внешней обработки как при выгрузке, так и при загрузке данных. И только после успешной выгрузки - загрузки в интерактивном режиме через промежуточный файл - пробовать синхронизацию через Веб.
 
9. Опыт внедрения

Данная схема успешно реализована в реальных действующих системах:

  • связка УТ 10.3 и УПП 1.3. (УТ нетиповая, доработана под производство с вводом данных через тач-панели на конвейерной линии)
  • связка Самописная конфигурация и БП 3.0 (В самописной конфигурации ведется учет технологических операций на фабрике птицы)
10. Состав вложенных файлов
  • ОбменДаннымиОнлайнЧерезВебСервис.cf - содержит все описанные объекты для синхронизации (Источник + Приемник). Обычные формы. Клиент-серверный вариант. В файловом варианте тоже все будет работать, кроме регламентного задания. В этом случае необходимо предусмотреть периодический запуск синхронизации с помощью метода ПодключитьОбработчикОжидания(). При сравнении, объединении необходимо отметить по подсистемам файла: подсистема "ЛУ_СинхронизацияЧерезВебСервис".
  • ДемоБазы.zip - содержит выгрузки из двух баз (PR1.dt и PR2.dt) для демонстрации готовой настроенной схемы синхронизации. Базы содержат простенькие документы и справочники. Имена метаданных синхронизируемых объектов различаются. Правила конвертации загружены в базу. Необходимо восстановить базы из .dt. Выполнить публикацию на Веб-сервере под именами PR1 и PR2 с установленной галочкой Публиковать Веб-сервисы и LuExchange. В режиме Предприятия в настройках соответствующих узлов планов обмена необходимо прописать имя Веб-сервера на котором была выполнена публикация баз.
  • ОбменДаннымиОнлайнЧерезВебСервис.cfe - вариант доработки в виде расширения конфигурации для баз находящихся на поддержке без возможности редактирования. Ввиду ограниченного функционала расширений, не содержит объекты: План обмена и Регламентное задание. То есть синхронизация здесь реализована без квитирования успешности доставки данных, но полностью совместима с протоколом обмена основного .cf

11. Инструкция по внедрению (ОбменДаннымиОнлайнЧерезВебСервис.cf)

Скачиваем файл ОбменДаннымиОнлайнЧерезВебСервис.cf

Выполняем команду: Конфигурация - Сравнить, объединить с конфигурацией из файла...
После вывода результатов сравнения конфигураций выполняем команду:
Действия - Отметить по подсистемам файла - отмечаем подсистему "ЛУ_СинхронизацияЧерезВебСервис".
Далее - Выполнить.
Обновляем конфигурацию базы данных.
 
То же повторяем для корреспондирующей базы.
 
Публикуем обе базы на Веб-сервере (Как? - это отдельная тема, поиск в помощь)
При публикации отмечаем галочками Публиковать Веб-сервисы и LuExchange.
 
Настраиваем соответствующие узлы Планов обменов обеих баз
В первой базе создаем узел с настройками подключения ко второй базе и наоборот.
Здесь:
  • Сервер - имя веб-сервера, на котором выполнена публикация баз
  • База - имя, под которым выполнена публикация корреспондирующей базы на веб-сервере, как правило совпадает с именем базы на сервере 1С Предприятие
  • Логин - имя пользователя, которого необходимо создать в обеих базах с ролью WebСервисLuExchange (подключение веб-сервиса будет происходить под этим пользователем)
  • Пароль
  • Правила конвертации - сюда необходимо загрузить правила конвертации, созданные в конфигурации "Конвертация данных"
Создание правил конвертации - тоже отдельная большая тема. (Если не в курсе, можно поштудировать инет)
Если Вы владеете этим мощным и универсальным инструментом, то для идентичных корреспондирующих баз, правила конвертации сможете создать полностью автоматически за несколько минут.
Открываем состав плана обмена ЛУ_WebСервис и добавляем все объекты, для которых в правилах конвертации прописали ПВД (Правила выгрузки данных).
Для всех объектов состава запрещаем авторегистрацию.
 
При разработке правил конвертации придерживаемся следующих рекомендаций:
  • Для ПВД поддерживается только способ выборки: "Стандартная выборка"
  • Для всех ПКО справочников и документов рекомендуется устанавливать в ИСТИНА следующие свойства:
    • Искать объект приемника по внутреннему идентификатору объекта источника;
    • При переносе объкта по ссылке НЕ создавать новый объект, а только переносить ссылку;
  • Для ПКО документов дополнительно рекомендуется устанавливать в ИСТИНА следующее свойство:
    • Не выгружать объекты свойств источника по ссылкам;

В этом случае файл данных XML для выгружаемого объекта не будет содержать объекты выгружаемые по ссылкам. Это существенно уменьшит размер передаваемых данных и ускорит процесс синхронизации. Выгрузка этих объектов при необходимости будет инициироваться автоматически.

Если возникнут затруднения в настройке планов обменов
можно скачать вложение "ДемоБазы.zip" и посмотреть как это выполнено в них.
 
Если понравилось и желаешь порекомендовать другим коллегам, ставь плюс!
174

Скачать файлы

Наименование Файл Версия Размер
ОбменДаннымиОнлайнЧерезВебСервис.cf
.cf 221,56Kb
07.02.19
74
.cf 1 221,56Kb 74 Скачать
ДемоБазы.zip
.zip 582,91Kb
07.02.19
50
.zip 1 582,91Kb 50 Скачать
ОбменДаннымиОнлайнЧерезВебСервисУФ.cfe (расширение конфигурации, управляемые формы)
.cfe 203,46Kb
06.11.16
40
.cfe 1.01 203,46Kb 40 Скачать

См. также

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. TODD22 17 31.10.16 14:04 Сейчас в теме
А какой объём данных можно передать за одно подключение?
У меня бывает пакеты по 30-40 Мб. На плохих каналах связи не всегда через ftp удаётся передать такой объём.
2. linkov 218 31.10.16 14:47 Сейчас в теме
(1) TODD22,

А какой объём данных можно передать за одно подключение?
У меня бывает пакеты по 30-40 Мб. На плохих каналах связи не всегда через ftp удаётся передать такой объём.

В представленной публикации алгоритм реализован именно для минимизации размера передаваемых данных через Веб-сервис.
Для этого:
- В одном пакете передается только один объект (элемент справочника или документ)
- Для документов в правилах конвертации отключена выгрузка объектов по ссылкам. Эта настройка существенно уменьшает размер передаваемых данных, исключая их избыточность. В случае необходимости, если подчиненный объект все же отсутствует в базе приемнике, то автоматически рекурсивно запускается его выгрузка в новых пакетах.
В итоге максимальный размер одного пакета в реальной схеме при синхронизации УПП 1.3 - УТ 10.3 для документа Поступление товаров и услуг (в среднем 10-20 строчек в табличной части) не превышает 0.5 Мб.

При стандартной установке для IIS максимальный размер обрабатываемого сообщения ~30 МБ

Если в Вашей схеме вес одного пакета зашкаливает за 30 Мб., то тогда Вам в помощь эта публикация: Передача больших пакетов через веб-сервисы
3. artbear 1109 02.11.16 20:13 Сейчас в теме
4. rash7wolf 05.11.16 20:08 Сейчас в теме
Приобрел оба файла. не жалею. все работает. спасибо ,нужная вещь . советую
5. a_titeev 7 09.12.16 10:46 Сейчас в теме
Зачем сервис для этого? Какие задачи это решает?
6. linkov 218 09.12.16 13:21 Сейчас в теме
(5)

Зачем сервис для этого? Какие задачи это решает?

Можно организовать онлайн обмен и без Веб-сервиса (в некоторых случаях), например используя COM-объект.
Здесь можно отметить преимущества и недостатки синхронизации через Веб-сервис в отличии от COM-объекта:

Недостатки COM-объекта:
1. Подключиться к базе через COM-объект вне локальной сети невозможно (хотя, если извратиться, то можно, но в любом случае, это вызовет хождение колоссального трафика). Через Веб-сервис можно легко обмениваться данными через интернет. В этом случае для безопасности необходимо подключаться используя SSL.

2. COM-объект - тяжелая штука. Ресурсы жрет немерено. Если у Вас работает несколько сотрудников, то скорее Вы этого не ощутите, а вот если 100-200 и все начнут что-то онлайн синхронить....

3. Для запуска COM-объекта требуется некоторое время.

4. Для COM-объекта обязательным условием для подключения является точное соответствие версии платформы базы Источника и базы Приемника. То есть, если Ваши базы находятся на разных серверах, обновление платформы 1С на обоих серверах необходимо производить одновременно!

Недостатки Веб-сервиса:
1. Стартует Веб-сервис быстро, даже при холодном старте, но пропускная способность http оставляет желать лучшего.

2. К недостаткам Веб-сервиса так же можно отнести необходимость заботиться о размере передаваемых данных, при стандартной настройке Веб-сервера IIS размер одного пакета данных не должен превышать 30Мб.
7. Ксакеп 58 20.01.17 10:54 Сейчас в теме
Разрабатываю похожий сервис, но несколько иного характера. Нет необходимости синхронизации "на лету". Столкнулся с проблемой подключения к веб-сервису с использованием шифрования. На клиенте все хорошо, 1с видит сертификат, считает ресурс надежным. На сервере же что только не перепробовал - "Удаленный узел не прошел проверку" и все. Хоть убей. Платформа 8.3.9.1818.

- добавлял сертификат в cacert.pem
- добавлял сертификат в доверенный центры
- подсовывал файл сертификата в ЗащищенноеСоединениеOpenSSL
- отключал проверку сертификата в ЗащищенноеСоединениеOpenSSL

Если зайти на сервер, открыть браузер, перейти по ссылке веб-сервиса, то браузер покажет что узел надежный.
8. linkov 218 20.01.17 12:04 Сейчас в теме
(7) Возможно при выпуске клиентского сертификата вы не указали политику применения - подтверждать подлинность клиента.
Если Вам не нужна проверка подлинности клиента, то в настройках Веб-сервера укажите - сертификат клиента игнорировать.
9. Ксакеп 58 20.01.17 12:29 Сейчас в теме
(8) я не выпускал клиентский сертификат. Был создан самоподписанный сертификат для сервера, и добавлен в системный список доверенных центров сертификации. И проблема именно в том, что сервер 1С не видит, что этот сертификат в доверенных, и, соответственно, не может доверять узлу, на котором расположен web-сервис.
10. linkov 218 20.01.17 13:00 Сейчас в теме
я не выпускал клиентский сертификат. Был создан самоподписанный сертификат для сервера, и добавлен в системный список доверенных центров сертификации. И проблема именно в том, что сервер 1С не видит, что этот сертификат в доверенных, и, соответственно, не может доверять узлу, на котором расположен web-сервис.

В моем случае все работало с использованием следующего кода, но сертификат был не самоподписанный:
ssl = Новый ЗащищенноеСоединениеOpenSSL();  
HTTPСоединение = Новый HTTPСоединение("gateway.*****.ru",, Логин, Пароль, ,, ssl);
HTTPЗапрос = Новый HTTPЗапрос("/base/hs/Exchange/info");
HTTPОтвет = HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);
11. Ксакеп 58 20.01.17 13:51 Сейчас в теме
(10) Если сертификат имеет подпись поверенного центра сертификации, строка: "ssl = Новый ЗащищенноеСоединениеOpenSSL()" вообще не требуется.

Кстати, по заявлению 1С, в 8.3.9 внесенго исправление, согласно которому, если ЗащищенноеСоединениеOpenSSL создать без указания хранилища серверных сертификатов, то проверка сертификата вообще не должна выполнятся. Однако выполняется.
12. linkov 218 20.01.17 13:54 Сейчас в теме
Не помню на какой версии платформы, это было в 2015 году, но только так и работало.
Возможно с тех пор все поменялось...
Ксакеп; +1 Ответить
13. murenysh 14 02.03.18 10:34 Сейчас в теме
Можно ли настроить обмен, чтобы опубликовать только одну базу?
14. linkov 218 02.03.18 10:49 Сейчас в теме
Можно, соответственно, данные будут синхронизироваться только в одну сторону.
15. murenysh 14 02.03.18 19:50 Сейчас в теме
но подтверждение о доставке тогда не будет работать.
Наемному бухгалтеру на компьютере ведь не будешь веб-сервер устанавливать.
Придется мучить стандартный Прочий обмен данными и обмен через ftp.
16. linkov 218 02.03.18 23:21 Сейчас в теме
(15)
но подтверждение о доставке тогда не будет работать.

Почему не будет? Будет. Алгоритм текущей доработки следующий:
При односторонней синхронизации на Веб-сервере публикуется только база-приемник.
База источник отправляет данные в базу приемник и не завершая сессию ждет ответ.
Если ответ положительный, то в плане обмена удаляется регистрация переданного объекта,
иначе не удаляется и при следующем запуске обмена повторяется попытка передачи этого объекта.
Но можно и наоборот, см.ниже.

Наемному бухгалтеру на компьютере ведь не будешь веб-сервер устанавливать.
Придется мучить стандартный Прочий обмен данными и обмен через ftp.

Для Вашего случая можно предложить переделать алгоритм следующим образом:
На веб-сервере публикуем только базу-источник.
В этом случае периферийная база должна выступать в роли инициатора обмена,
То есть, по инициативе пользователя или по регл.заданию выполняется запрос в базу-источник,
в ответ на который сервер должен передать данные очередного объекта.
Объект записывается в текущей базе, на сервер передается квитанция об успешности записи
и запрашивается очередной объект. До тех пор, пока сервер не ответит, что все объекты синхронизированы.
Этот вариант можно реализовать самостоятельно, используя те же методы получения данных объекта в формате XML
и обратного преобразования, описанных в публикации.
Не забудьте проконтролировать "фиктивные ссылки" и дополнительно запросить их данные с сервера.
17. murenysh 14 18.03.18 00:17 Сейчас в теме
К сожалению не смог применить к своей задаче данную разработку.
1. Если не выгружать подчиненные по ссылке, то база-приемник запросит недостающие объекты, но в будущем, если в источнике изменят например номенклатуру, то изменения не попадут в приемник.

2. Изменения в нужных для обмена документах происходят не только интерактивно, но и программно, например пакетами загружаются с сайта. Запускать обмен при получении каждого документа невозможно.

Еще в коде непонятно, чем отличается
ОбъектРегистрации = Новый УдалениеОбъекта(Источник.Ссылка);
ПланыОбмена.ЗарегистрироватьИзменения(ТекущийУзел, ОбъектРегистрации);


от
ПланыОбмена.ЗарегистрироватьИзменения(ТекущийУзел, Источник.Ссылка);


ведь в первом случае все равно регистрируется просто ссылка из УдалениеОбъекта

"Но с данным кодом возникнет следующая проблема – при наличии строки Удаление.Записать(); будет удален объект в текущей базе (а это не нужно). При отсутствии строки Удаление.Записать(); в удаленной базе данные останутся, то есть задача не будет решена."
https://infostart.ru/public/188547/
18. linkov 218 19.03.18 21:29 Сейчас в теме
(17)
1. Если не выгружать подчиненные по ссылке, то база-приемник запросит недостающие объекты, но в будущем, если в источнике изменят например номенклатуру, то изменения не попадут в приемник.

Смотри внимательнее подписки:
Источник - СправочникОбъект, ДокументОбъект
то есть, при изменении Номенклатуры, так же запуститься синхронизация и данный элемент будет синхронизирован!

2. Изменения в нужных для обмена документах происходят не только интерактивно, но и программно, например пакетами загружаются с сайта. Запускать обмен при получении каждого документа невозможно.

В данных алгоритмах целенаправленно была реализована выборочная регистрация измененных объектов в плане обмена только при интерактивной записи (по условиям задания).
В Вашем же случае все гораздо проще: убираем соответствующие подписки для регистрации объектов, активируем автоматическую регистрацию в плане обмена типовыми средствами, а после загрузки данных с сайта вызываем синхронизацию процедурой:
ЛУ_СинхронизацияВызовСервера.ПланОбменаСинхронизироватьАсинхронно(ПланОбменаМетаданные.Имя);
либо вешаем этот метод на регламентное задание с нужной периодичностью.

3. Еще в коде непонятно, чем отличается ... от ... ведь в первом случае все равно регистрируется просто ссылка из УдалениеОбъекта

Опять, читаем код более внимательно:
Объект УдалениеОбъекта в данном случае нужен исключительно для того, чтобы далее, при чтении изменений из плана обмена для отправки в кор. базу отличать измененные объекты от удаленных,
соответственно массив удаленных объектов отправляется в кор.базу собственным методом,
см.
Если ТипЗнч(Объект) = Тип("УдалениеОбъекта") Тогда
				МассивУдаляемыхОбъектов.Добавить(Объект);


Далее:
ВыгрузитьУдаляемыеОбъектыВБазуПриемник(ТекущийУзел, МассивУдаляемыхОбъектов, LuExchange, ОбработкаОбмена, ФайлОбмена, ИмяСобытияДляЖурнала, Отказ);


Ну, и на стороне базы приемника:
Функция DeleteObject(TypeOf, UUID, ErrorMessage)
19. murenysh 14 20.03.18 01:39 Сейчас в теме
Если ТипЗнч(Объект) = Тип("УдалениеОбъекта") Тогда
                МассивУдаляемыхОбъектов.Добавить(Объект);

В этом коде МассивУдаляемыхОбъектов будет всегда пустым, так как УдалениеОбъекта без выполненного метода Записать попадает в УзелОбмена как ссылка на измененный объект, а не как объект УдалениеОбъекта.


Я предположил, что раз есть механизм фиктивных ссылок, то включать подчиненные справочники в состав плана обмена не нужно. Ведь если регистрировать все подчиненные справочники, то механизм фиктивных ссылок становится не нужен.


Смотри внимательнее подписки:

Опять, читаем код более внимательно:

Лучше без этого
20. linkov 218 20.03.18 13:22 Сейчас в теме
(19)
Лучше без этого

- Согласен, действительно получилось не очень корректно.
Исправлюсь)

В этом коде МассивУдаляемыхОбъектов будет всегда пустым, так как УдалениеОбъекта без выполненного метода Записать попадает в УзелОбмена как ссылка на измененный объект, а не как объект УдалениеОбъекта.

Но по факту - не пустой!)
Метод Записать(), инициирующий удаление объекта, в данном случае не используется, так как код и так выполняется в подписке ПередУдалением.
Здесь важно, чтобы на момент чтения изменений из плана обмена, объект уже был удален. Это достигается тем, что соответствующий участок кода выполняется асинхронно в фоновом задании, которое стартует с некоторой задержкой, после того, как отработает подписка ПередУдалением и транзакция удаления объекта уже завершилась.

Я предположил, что раз есть механизм фиктивных ссылок, то включать подчиненные справочники в состав плана обмена не нужно. Ведь если регистрировать все подчиненные справочники, то механизм фиктивных ссылок становится не нужен.

Тут главное отличие механизма Фиктивных ссылок (с регистрацией всех подчиненных справочников) от выгрузки По ссылкам в том, что
в первом случае элементы справочников синхронизируются только при изменении, либо отсутствии подчиненной ссылки в базе назначения (фиктивная ссылка),
Этим как раз и достигается основной эффект уменьшения размера пакетов передаваемых данных и существенного увеличения скорости обмена.

во втором случае (при выгрузке по ссылкам) каждый раз при выгрузке документа вместе с ним выгружаются все подчиненные справочники.
21. murenysh 14 22.03.18 11:45 Сейчас в теме
(20)
Это достигается тем, что соответствующий участок кода выполняется асинхронно в фоновом задании, которое стартует с некоторой задержкой, после того, как отработает подписка ПередУдалением и транзакция удаления объекта уже завершилась.

Интересная комбинация. Протестировать затратно по времени, но раз работает, то работает.


(20)
во втором случае (при выгрузке по ссылкам) каждый раз при выгрузке документа вместе с ним выгружаются все подчиненные справочники.

Я предполагал третий вариант. Первичная выгрузка документов делается с выгрузкой подчиненных объектов по ссылкам, потом выгрузка подчиненных по ссылкам у документов отключается и подчиненные выгружаются только при их изменении и попадании в регистрацию узла обмена.
В таком случае и файл обмена небольшой и дополнительный механизм фиктивных ссылок не нужен.
22. xan333 34 26.04.18 16:31 Сейчас в теме
Добрый день! 12. Инструкция по внедрению Расширения конфигурации (ОбменДаннымиОнлайнЧерезВебСервис.cfe)
(в процессе, будет чуть позже) есть где то? Не хочется снимать конфигурацию с поддержки.
23. demart-omsk 17 23.06.18 00:32 Сейчас в теме
Спасибо, пригодилось! Все отлично работает.
24. mars207 27 25.07.18 16:56 Сейчас в теме
Все работает, большое спасибо!!!
Оставьте свое сообщение